SKU:RB-02S020A DS18B20數(shù)字溫度傳感器

產(chǎn)品概述

最新推出的DS18B20數(shù)字溫度傳感器采用美國(guó)DALLAS公司生產(chǎn)的DS18B20一總線數(shù)字溫度感測(cè)元件其測(cè)溫范圍－55℃～＋125℃，固有測(cè)溫分辨率0.5℃，支持多點(diǎn)組網(wǎng)功能，多個(gè)DS18B20可以并聯(lián)在唯一的三線上，實(shí)現(xiàn)多點(diǎn)測(cè)溫，測(cè)量結(jié)果以9~12位數(shù)字量方式串行傳送。 DS18B20數(shù)字溫度傳感器可在各種單片機(jī)控制器上應(yīng)用，尤其在Arduino控制器上更為簡(jiǎn)單，現(xiàn)成庫(kù)函數(shù)調(diào)用，即可完成溫度測(cè)量，通過(guò)3P傳感器連接線插接到Arduino專(zhuān)用傳感器擴(kuò)展板上，可以非常容易地實(shí)現(xiàn)與環(huán)境溫度感知相關(guān)的互動(dòng)作品。

規(guī)格參數(shù)

類(lèi)型：數(shù)字模塊（一總線接口）
可用于檢測(cè)周?chē)諝鉁囟?
溫度測(cè)量范圍：－55℃～＋125℃
測(cè)量精度：±0.5 °C（-10 °C至+85 °C范圍內(nèi)）
9位～12位A/D轉(zhuǎn)換精度
分辨率：0.5℃
供電電壓：3.3V或5V

接口定義

S：輸出信號(hào)
+：電源(VCC)
-：地(GND)

使用方法

工作原理

DS18B20 是一款常用的數(shù)字溫度傳感器，DS18B20 主要由 64 位光刻 ROM、溫度傳感器、非揮發(fā)的溫度報(bào)警觸發(fā)器 TH 和 TL、配置寄存器等四部分組成，具有體積小，使用方便，抗干擾能力強(qiáng)，精度高等特點(diǎn)，適用于各種狹小空間數(shù)字測(cè)溫和控制領(lǐng)域。
DS18B20 提供9位（二進(jìn)制）溫度讀數(shù)來(lái)表示所測(cè)的溫度值，采用單線接口，使用時(shí)，僅需要一條口線即可實(shí)現(xiàn)與單片機(jī)的雙向通信，簡(jiǎn)化了分布式溫度傳感器的應(yīng)用。在使用中不需要任何外圍元件，且支持多點(diǎn)組網(wǎng)的功能，多個(gè) DS18B20 可以并聯(lián)在唯一的三線上，最多可并聯(lián)8個(gè)，實(shí)現(xiàn)多點(diǎn)測(cè)溫。溫度測(cè)量范圍是 -55 - +125℃，固有測(cè)溫分辨率為 ±0.5℃，可在 1 秒內(nèi)把溫度變換成數(shù)字信號(hào)輸出。
DS18B20 有兩種供電方式，即數(shù)據(jù)總線供電方式與外部供電方式，采用數(shù)據(jù)總線供電雖然可以節(jié)省一根導(dǎo)線，但完成溫度測(cè)量的時(shí)間較長(zhǎng)；采取外部供電方式雖然多用了一根導(dǎo)線，但是測(cè)量速度較快，可以根據(jù)實(shí)際需求選擇供電方式。

編程原理

數(shù)字溫度傳感器模塊引出三個(gè)接口，包含有數(shù)據(jù)線 S，電源 Vcc 和地線 GND，實(shí)際應(yīng)用時(shí)，可以將數(shù)據(jù)線 S 端與 Arduino 控制器的數(shù)字引腳連接，如 D2，Arduino 專(zhuān)門(mén)提供了可供調(diào)用的庫(kù)函數(shù)，該函數(shù)的文件名分別為 DallasTemperature 和 OneWire，您可以直接從此下載庫(kù)文件，然后把該庫(kù)文件復(fù)制到 Arduino 集成開(kāi)發(fā)環(huán)境的安裝目錄下的 Libraries 文件夾下。通過(guò)分別在程序中引用 DallasTemperature.h 和 OneWire.h，并分別實(shí)例化對(duì)象 OneWire 和 Sensor 類(lèi)，直接使用類(lèi)的成員函數(shù)來(lái)實(shí)現(xiàn)數(shù)字傳感器的溫度采集。

硬件設(shè)備

我們使用Arduino控制器來(lái)做個(gè)測(cè)試，要用到硬件設(shè)備如下：

Carduino UNO 控制器 * 1個(gè)
傳感器擴(kuò)展板V5.0 * 1個(gè)
DS18B20 溫度傳感器模塊 * 1個(gè)
通用3P傳感器連接線 * 1個(gè)
USB 數(shù)據(jù)通信線 * 1個(gè)

程序1接線圖

例子程序1

DS18B20溫度傳感器庫(kù)文件下載

如程序1接線圖所示，使用傳感器連接線將DS18B20 溫度傳感器連接到Arduino傳感器擴(kuò)展板的數(shù)字接口。先把下載的庫(kù)文件解壓縮到你的Arduino安裝目錄下的hardware\libraries 里面。然后將代碼編譯后下載到Arduino里，就可以在串口助手窗口上顯示測(cè)得的當(dāng)前值。

#include <OneWire.h>
#include <DallasTemperature.h>
 
// 定義DS18B20數(shù)據(jù)口連接arduino的2號(hào)IO上
#define ONE_WIRE_BUS 2
 
// 初始連接在單總線上的單總線設(shè)備
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
 
void setup(void)
{
  // 設(shè)置串口通信波特率
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");
 
  // 初始庫(kù)
  sensors.begin();
}
 
void loop(void)
{ 
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // 發(fā)送命令獲取溫度
  Serial.println("DONE");
   
  Serial.print("Temperature for the device 1 (index 0) is: ");
  Serial.println(sensors.getTempCByIndex(0));  
}

程序1效果

程序2接線圖

例子程序2

DS18B20溫度傳感器庫(kù)文件下載

如程序2接線圖所示，使用傳感器連接線將DS18B20 溫度傳感器連接到Arduino傳感器擴(kuò)展板的數(shù)字接口。先把下載的庫(kù)文件解壓縮到你的Arduino安裝目錄下的hardware\libraries 里面。然后將代碼編譯后下載到Arduino里，就可以在串口助手窗口上顯示測(cè)得的當(dāng)前值。

#include <OneWire.h>
OneWire  ds(10);  // 連接arduino10引腳
void setup(void) {
  Serial.begin(9600);
}
void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }
 
  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
  
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 
 
  ds.reset();
  ds.select(addr);
  ds.write(0x44,1);         // start conversion, with parasite power on at the end
   
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
   
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad
 
  Serial.print("  Data = ");
  Serial.print(present,HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();
  // convert the data to actual temperature
  unsigned int raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // count remain gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    if (cfg == 0x00) raw = raw << 3;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw << 2; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw << 1; // 11 bit res, 375 ms
    // default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");   
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}

程序2效果

應(yīng)用視頻

產(chǎn)品相關(guān)推薦

購(gòu)買(mǎi)地址

DS18B20 數(shù)字溫度傳感器