查看(SKU:RB-02S041)夏普GP2D12紅外測距傳感器的源代碼

[[文件:RB-02S041.jpg|500px|縮略圖|右]]
==產(chǎn)品概述==
GP2D12 IR Sensor 是日本夏普公司推出的一款性價比高、最常用的紅外測距傳感器、其可用來對物體的距離進行測量，實現(xiàn)輪式機器人的避障功能。它不但體積小、功耗低、價格便宜，而且測距效果好，適合廣大機器人發(fā)燒友使用。
==規(guī)格參數(shù)==
# 測量射程范圍：10 to 80 cm 
# 最大允許角度：>40° 
# 電源電壓：4.5 to 5.5V 
# 平均功耗：35mA 
# 峰值功耗：約200mA 
# 更新頻率/周期：25Hz/40ms 
# 模擬輸出噪聲：<200mV 
# 測量距離與輸出模擬電壓關系：2.4V~0.4V模擬信號對應10cm~80cm，輸出與距離成反比非線性關系
==使用方法==
===引腳定義===
* Vo：輸出引腳
* GND:電源地
* Vcc：電源正極
===產(chǎn)品尺寸圖===
[[文件:RB-02S0411.jpg|700px|縮略圖|居中]]
===模擬信號與測量距離對應表===
[[文件:RB-02S0412.jpg|700px|縮略圖|居中]]
===信號輸出===
ADC0831可以將模擬信號轉(zhuǎn)為數(shù)字信號輸出
[[文件:RB-02S0413.jpg|700px|縮略圖|居中]]
==應用例程==
首先將距離傳感器固定到舵機上，可以使用熱熔膠或者膠帶。然后使用一個1uf電解電容和一個22uf電解電容并聯(lián)在5V穩(wěn)壓芯片L4940V5上。將紅外距離傳感器的信號線插入0號模擬引腳。4個LED通過1KΩ電阻插入3、5、6、11引腳。最后將舵機信號線接在9號引腳上。
===連接示意圖===
[[文件:RB-02S0414.jpg|700px|縮略圖|居中]]
===示例代碼1===
<pre style='color:blue'>#include <Servo.h>

 const int SERVO  =9;   //伺服電機連接在9號引腳
 const int IR     =0;   //紅外距離傳感器連接在0號模擬引腳
 const int LED1   =3;   //LED輸出1
 const int LED2   =5;   //LED輸出2
 const int LED3   =6;   //LED 輸出3
 const int LED4   =11;  //LED 輸出4

Servo myServo;     //伺服電機對象
int dist1 = 0;     //第一象限距離
int dist2 = 0;     //第二象限距離
int dist3 = 0;     //第三象限距離
int dist4 = 0;     //第四象限距離

void setup()
{
    myServo.attach(SERVO); //綁定伺服電機
    pinMode(LED1, OUTPUT); //將LED設置為輸出
    pinMode(LED2, OUTPUT); //將LED設置為輸出
    pinMode(LED3, OUTPUT); //將LED設置為輸出
    pinMode(LED4, OUTPUT); //將LED設置為輸出
}

void loop()
{
    //將伺服電機在4個區(qū)域中掃描并改變LED亮度
    dist1 = readDistance(15);     //在15°處進行紅外測距
    analogWrite(LED1, dist1);     //調(diào)節(jié)LED亮度
    delay(300);                   //下次測量前的延時
 
    dist2 = readDistance(65);     //在65°處進行紅外測距
    analogWrite(LED2, dist2);     //調(diào)節(jié)LED亮度
    delay(300);                   //下次測量前的延時
 
    dist3 = readDistance(115);    //在115°處進行紅外測距
    analogWrite(LED3, dist3);     //調(diào)節(jié)LED亮度
    delay(300);                   //下次測量前的延時
 
    dist4 = readDistance(165);    //在165°處進行紅外測距
    analogWrite(LED4, dist4);     //調(diào)節(jié)LED亮度
    delay(300);                   //下次測量前的延時
}

int readDistance(int pos)
{
    myServo.write(pos);                //轉(zhuǎn)動到指定位置
    delay(600);                        //等待伺服電機轉(zhuǎn)動
    int dist = analogRead(IR);         //讀取紅外傳感器
    dist = map(dist, 50, 500, 0, 255); //轉(zhuǎn)換到LED的范圍內(nèi) 
    dist = constrain(dist, 0, 255);    //約束它
    return dist;                       //返回縮放后的距離
}</pre>
===程序效果===
當舵機轉(zhuǎn)動到一個給定的位置時測定距離，將其轉(zhuǎn)換為LED的亮度值，改變LED的亮度值，將其轉(zhuǎn)向下一個位置，然后繼續(xù)，如此重復。
==示例代碼2==
將傳感器連接到UNO控制器模擬口A1上，將以下代碼下載到UNO控制器中
<pre style="color:blue">
/******** start code ********/
/*
 * function:	test gp2d120x
 * VCC -- VCC
 * GND -- GND
 * Signal -- Analog 1 
 *
 */

#define pin A1

void setup () {
        Serial.begin (9600);
        pinMode (pin, INPUT);
}

void loop () {
        uint16_t value = analogRead (pin);
        double distance = get_gp2d120x (value);
        Serial.println (value);
        Serial.print (distance);
        Serial.println (" cm");
        Serial.println ();
        delay (500);
}

//return distance (cm)
double get_gp2d120x (uint16_t value) {
        if (value < 16)  value = 16;
        return 2076.0 / (value - 11.0);
}

/******** end code ********/
</pre>
==產(chǎn)品相關推薦==
購買地址：[http://lifestyle201.com/goods-181.html 夏普GP2D12紅外測距傳感器]